English | Français | Deutsch | Magyar | 中文 | >> Polski << ZVON > Tutorials > XSLT Tutorial
Wstęp / Szukaj / ZVON
>> Strona 70 << | Poprzedni | Następny | Zawartość | Indeks elementu

Element xsl:apply-imports może być użyty by uzyskać informację z importowanego szablonu, gdy jego zachowanie zmienia się. Arkusz stylów XSLT 2 importuje Arkusz stylów XSLT 1 oraz nadpisuje jego szablony. Arkusz stylów XSLT 3 importuje Arkusz stylów XSLT 1 oraz zmienia jego szablony. xsl-apply-imports działa tylko w przypadku importowania przy użyciu xsl:import, nie zadziała natomiast gdy użyto xsl:include ( Arkusz stylów XSLT 4 ).

Arkusz stylów XSLT 1

Źródło XML
<source>

<AAA/>
<BBB/>
<CCC/>

</source>

Dane wyjściowe
<DIV style="color:red">AAA</DIV>

<DIV style="color:red">BBB</DIV>

<DIV style="color:red">CCC</DIV>

Widok HTML
AAA
BBB
CCC
Arkusz stylów XSLT (file: id2.xsl )
<xsl:stylesheet version = '1.0'
     xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>

<xsl:template match="/*/*">
     <DIV style="color:red">
          <xsl:value-of select="name()"/>
     </DIV>
</xsl:template>


</xsl:stylesheet>


Arkusz stylów XSLT 2

Źródło XML
<source>

<AAA/>
<BBB/>
<CCC/>

</source>

Dane wyjściowe
<EM>AAA</EM>

<EM>BBB</EM>

<EM>CCC</EM>

Widok HTML
AAA BBB CCC
Arkusz stylów XSLT (file: id3.xsl )
<xsl:stylesheet version = '1.0'
     xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>

<xsl:import href="id2.xsl"/>
<xsl:template match="/*/*">
     <EM>
          <xsl:value-of select="name()"/>
     </EM>
</xsl:template>


</xsl:stylesheet>


Arkusz stylów XSLT 3

Źródło XML
<source>

<AAA/>
<BBB/>
<CCC/>

</source>

Dane wyjściowe
<EM>
  <DIV style="color:red">AAA</DIV>
</EM>

<EM>
  <DIV style="color:red">BBB</DIV>
</EM>

<EM>
  <DIV style="color:red">CCC</DIV>
</EM>

Widok HTML
AAA
BBB
CCC
Arkusz stylów XSLT (file: id4.xsl )
<xsl:stylesheet version = '1.0'
     xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>

<xsl:import href="id2.xsl"/>
<xsl:template match="/*/*">
     <EM>
          <xsl:apply-imports/>
     </EM>
</xsl:template>


</xsl:stylesheet>


Arkusz stylów XSLT 4

Źródło XML
<source>

<AAA/>
<BBB/>
<CCC/>

</source>

Dane wyjściowe
<EM/>

<EM/>

<EM/>

Widok HTML
Arkusz stylów XSLT (file: id5.xsl )
<xsl:stylesheet version = '1.0'
     xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>

<xsl:include href="id2.xsl"/>
<xsl:template match="/*/*">
     <EM>
          <xsl:apply-imports/>
     </EM>
</xsl:template>


</xsl:stylesheet>