32. Markers

• Overview of Markers
• Predicates on Markers
• Functions That Create Markers
• Information from Markers
• Marker Insertion Types
• Moving Marker Positions
• The Mark
• The Region

A marker is a Lisp object used to specify a position in a buffer relative to the surrounding text. A marker changes its offset from the beginning of the buffer automatically whenever text is inserted or deleted, so that it stays with the two characters on either side of it.

^top next
32.1. Overview of Markers

A marker specifies a buffer and a position in that buffer. The marker can be used to represent a position in the functions that require one, just as an integer could be used. See section Positions, for a complete description of positions.

A marker has two attributes: the marker position, and the marker buffer. The marker position is an integer that is equivalent (at a given time) to the marker as a position in that buffer. But the marker's position value can change often during the life of the marker. Insertion and deletion of text in the buffer relocate the marker. The idea is that a marker positioned between two characters remains between those two characters despite insertion and deletion elsewhere in the buffer. Relocation changes the integer equivalent of the marker.

Deleting text around a marker's position leaves the marker between the characters immediately before and after the deleted text. Inserting text at the position of a marker normally leaves the marker either in front of or after the new text, depending on the marker's insertion type (see section Marker Insertion Types)---unless the insertion is done with insert-before-markers (see section Inserting Text).

Insertion and deletion in a buffer must check all the markers and relocate them if necessary. This slows processing in a buffer with a large number of markers. For this reason, it is a good idea to make a marker point nowhere if you are sure you don't need it any more. Unreferenced markers are garbage collected eventually, but until then will continue to use time if they do point somewhere.

Because it is common to perform arithmetic operations on a marker position, most of the arithmetic operations (including + and -) accept markers as arguments. In such cases, the marker stands for its current position.

Here are examples of creating markers, setting markers, and moving point to markers:

;; Make a new marker that initially does not point anywhere:
(setq m1 (make-marker))
     => #<marker in no buffer>

;; Set m1 to point between the 99th and 100th characters
;;   in the current buffer:
(set-marker m1 100)
     => #<marker at 100 in markers.texi>

;; Now insert one character at the beginning of the buffer:
(goto-char (point-min))
     => 1
(insert "Q")
     => nil

;; m1 is updated appropriately.
m1
     => #<marker at 101 in markers.texi>

;; Two markers that point to the same position
;;   are not eq, but they are equal.
(setq m2 (copy-marker m1))
     => #<marker at 101 in markers.texi>
(eq m1 m2)
     => nil
(equal m1 m2)
     => t

;; When you are finished using a marker, make it point nowhere.
(set-marker m1 nil)
     => #<marker in no buffer>

^{top next prev}
32.2. Predicates on Markers

You can test an object to see whether it is a marker, or whether it is either an integer or a marker. The latter test is useful in connection with the arithmetic functions that work with both markers and integers.

^topFunction: markerp object

This function returns t if object is a marker, nil otherwise. Note that integers are not markers, even though many functions will accept either a marker or an integer.

^topFunction: integer-or-marker-p object

This function returns t if object is an integer or a marker, nil otherwise.

^topFunction: number-or-marker-p object

This function returns t if object is a number (either integer or floating point) or a marker, nil otherwise.

^{top next prev}
32.3. Functions That Create Markers

When you create a new marker, you can make it point nowhere, or point to the present position of point, or to the beginning or end of the accessible portion of the buffer, or to the same place as another given marker.

^topFunction: make-marker

This function returns a newly created marker that does not point anywhere.

(make-marker)
     => #<marker in no buffer>

^topFunction: point-marker

This function returns a new marker that points to the present position of point in the current buffer. See section Point. For an example, see copy-marker, below.

^topFunction: point-min-marker

This function returns a new marker that points to the beginning of the accessible portion of the buffer. This will be the beginning of the buffer unless narrowing is in effect. See section Narrowing.

^topFunction: point-max-marker

This function returns a new marker that points to the end of the accessible portion of the buffer. This will be the end of the buffer unless narrowing is in effect. See section Narrowing.

Here are examples of this function and point-min-marker, shown in a buffer containing a version of the source file for the text of this chapter.

(point-min-marker)
     => #<marker at 1 in markers.texi>
(point-max-marker)
     => #<marker at 15573 in markers.texi>

(narrow-to-region 100 200)
     => nil
(point-min-marker)
     => #<marker at 100 in markers.texi>
(point-max-marker)
     => #<marker at 200 in markers.texi>

^topFunction: copy-marker marker-or-integer insertion-type

If passed a marker as its argument, copy-marker returns a new marker that points to the same place and the same buffer as does marker-or-integer. If passed an integer as its argument, copy-marker returns a new marker that points to position marker-or-integer in the current buffer.

The new marker's insertion type is specified by the argument insertion-type. See section Marker Insertion Types.

If passed an integer argument less than 1, copy-marker returns a new marker that points to the beginning of the current buffer. If passed an integer argument greater than the length of the buffer, copy-marker returns a new marker that points to the end of the buffer.

(copy-marker 0)
     => #<marker at 1 in markers.texi>

(copy-marker 20000)
     => #<marker at 7572 in markers.texi>

An error is signaled if marker is neither a marker nor an integer.

Two distinct markers are considered equal (even though not eq) to each other if they have the same position and buffer, or if they both point nowhere.

(setq p (point-marker))
     => #<marker at 2139 in markers.texi>

(setq q (copy-marker p))
     => #<marker at 2139 in markers.texi>

(eq p q)
     => nil

(equal p q)
     => t

^{top next prev}
32.4. Information from Markers

This section describes the functions for accessing the components of a marker object.

^topFunction: marker-position marker

This function returns the position that marker points to, or nil if it points nowhere.

^topFunction: marker-buffer marker

This function returns the buffer that marker points into, or nil if it points nowhere.

(setq m (make-marker))
     => #<marker in no buffer>
(marker-position m)
     => nil
(marker-buffer m)
     => nil

(set-marker m 3770 (current-buffer))
     => #<marker at 3770 in markers.texi>
(marker-buffer m)
     => #<buffer markers.texi>
(marker-position m)
     => 3770

^{top next prev}
32.5. Marker Insertion Types

When you insert text directly at the place where a marker points, there are two possible ways to relocate that marker: it can point before the inserted text, or point after it. You can specify which one a given marker should do by setting its insertion type. Note that use of insert-before-markers ignores markers' insertion types, always relocating a marker to point after the inserted text.

^topFunction: set-marker-insertion-type marker type

This function sets the insertion type of marker marker to type. If type is t, marker will advance when text is inserted at its position. If type is nil, marker does not advance when text is inserted there.

^topFunction: marker-insertion-type marker

This function reports the current insertion type of marker.

^{top next prev}
32.6. Moving Marker Positions

This section describes how to change the position of an existing marker. When you do this, be sure you know whether the marker is used outside of your program, and, if so, what effects will result from moving it--otherwise, confusing things may happen in other parts of Emacs.

^topFunction: set-marker marker position &optional buffer

This function moves marker to position in buffer. If buffer is not provided, it defaults to the current buffer.

If position is less than 1, set-marker moves marker to the beginning of the buffer. If position is greater than the size of the buffer, set-marker moves marker to the end of the buffer. If position is nil or a marker that points nowhere, then marker is set to point nowhere.

The value returned is marker.

(setq m (point-marker))
     => #<marker at 4714 in markers.texi>
(set-marker m 55)
     => #<marker at 55 in markers.texi>
(setq b (get-buffer "foo"))
     => #<buffer foo>
(set-marker m 0 b)
     => #<marker at 1 in foo>

^topFunction: move-marker marker position &optional buffer

This is another name for set-marker.

^{top next prev}
32.7. The Mark

One special marker in each buffer is designated the mark. It records a position for the user for the sake of commands such as kill-region and indent-rigidly. Lisp programs should set the mark only to values that have a potential use to the user, and never for their own internal purposes. For example, the replace-regexp command sets the mark to the value of point before doing any replacements, because this enables the user to move back there conveniently after the replace is finished.

Many commands are designed so that when called interactively they operate on the text between point and the mark. If you are writing such a command, don't examine the mark directly; instead, use interactive with the `r' specification. This provides the values of point and the mark as arguments to the command in an interactive call, but permits other Lisp programs to specify arguments explicitly. See section Code Characters for interactive.

Each buffer has its own value of the mark that is independent of the value of the mark in other buffers. When a buffer is created, the mark exists but does not point anywhere. We consider this state as "the absence of a mark in that buffer."

Once the mark "exists" in a buffer, it normally never ceases to exist. However, it may become inactive, if Transient Mark mode is enabled. The variable mark-active, which is always buffer-local in all buffers, indicates whether the mark is active: non-nil means yes. A command can request deactivation of the mark upon return to the editor command loop by setting deactivate-mark to a non-nil value (but this causes deactivation only if Transient Mark mode is enabled).

The main motivation for using Transient Mark mode is that this mode also enables highlighting of the region when the mark is active. See section Emacs Display.

In addition to the mark, each buffer has a mark ring which is a list of markers containing previous values of the mark. When editing commands change the mark, they should normally save the old value of the mark on the mark ring. The variable mark-ring-max specifies the maximum number of entries in the mark ring; once the list becomes this long, adding a new element deletes the last element.

^topFunction: mark &optional force

This function returns the current buffer's mark position as an integer.

If the mark is inactive, mark normally signals an error. However, if force is non-nil, then mark returns the mark position anyway--or nil, if the mark is not yet set for this buffer.

^topFunction: mark-marker

This function returns the current buffer's mark. This is the very marker that records the mark location inside Emacs, not a copy. Therefore, changing this marker's position will directly affect the position of the mark. Don't do it unless that is the effect you want.

(setq m (mark-marker))
     => #<marker at 3420 in markers.texi>
(set-marker m 100)
     => #<marker at 100 in markers.texi>
(mark-marker)
     => #<marker at 100 in markers.texi>

Like any marker, this marker can be set to point at any buffer you like. We don't recommend that you make it point at any buffer other than the one of which it is the mark. If you do, it will yield perfectly consistent, but rather odd, results.

^topFunction: set-mark position

This function sets the mark to position, and activates the mark. The old value of the mark is not pushed onto the mark ring.

Please note: Use this function only if you want the user to see that the mark has moved, and you want the previous mark position to be lost. Normally, when a new mark is set, the old one should go on the mark-ring. For this reason, most applications should use push-mark and pop-mark, not set-mark.

Novice Emacs Lisp programmers often try to use the mark for the wrong purposes. The mark saves a location for the user's convenience. An editing command should not alter the mark unless altering the mark is part of the user-level functionality of the command. (And, in that case, this effect should be documented.) To remember a location for internal use in the Lisp program, store it in a Lisp variable. For example:

(let ((beg (point)))
  (forward-line 1)
  (delete-region beg (point))).

^topFunction: push-mark &optional position nomsg activate

This function sets the current buffer's mark to position, and pushes a copy of the previous mark onto mark-ring. If position is nil, then the value of point is used. push-mark returns nil.

The function push-mark normally does not activate the mark. To do that, specify t for the argument activate.

A `Mark set' message is displayed unless nomsg is non-nil.

^topFunction: pop-mark

This function pops off the top element of mark-ring and makes that mark become the buffer's actual mark. This does not move point in the buffer, and it does nothing if mark-ring is empty. It deactivates the mark.

The return value is not meaningful.

^topUser Option: transient-mark-mode

This variable if non-nil enables Transient Mark mode, in which every buffer-modifying primitive sets deactivate-mark. The consequence of this is that commands that modify the buffer normally make the mark inactive.

^topUser Option: mark-even-if-inactive

If this is non-nil, Lisp programs and the Emacs user can use the mark even when it is inactive. This option affects the behavior of Transient Mark mode. When the option is non-nil, deactivation of the mark turns off region highlighting, but commands that use the mark behave as if the mark were still active.

^topVariable: deactivate-mark

If an editor command sets this variable non-nil, then the editor command loop deactivates the mark after the command returns (if Transient Mark mode is enabled). All the primitives that change the buffer set deactivate-mark, to deactivate the mark when the command is finished.

^topFunction: deactivate-mark

This function deactivates the mark, if Transient Mark mode is enabled. Otherwise it does nothing.

^topVariable: mark-active

The mark is active when this variable is non-nil. This variable is always buffer-local in each buffer.

^topVariable: activate-mark-hook

^topVariable: deactivate-mark-hook

These normal hooks are run, respectively, when the mark becomes active and when it becomes inactive. The hook activate-mark-hook is also run at the end of a command if the mark is active and it is possible that the region may have changed.

^topVariable: mark-ring

The value of this buffer-local variable is the list of saved former marks of the current buffer, most recent first.

mark-ring
=> (#<marker at 11050 in markers.texi> 
    #<marker at 10832 in markers.texi>
    ...)

^topUser Option: mark-ring-max

The value of this variable is the maximum size of mark-ring. If more marks than this are pushed onto the mark-ring, push-mark discards an old mark when it adds a new one.

^top prev
32.8. The Region

The text between point and the mark is known as the region. Various functions operate on text delimited by point and the mark, but only those functions specifically related to the region itself are described here.

^topFunction: region-beginning

This function returns the position of the beginning of the region (as an integer). This is the position of either point or the mark, whichever is smaller.

If the mark does not point anywhere, an error is signaled.

^topFunction: region-end

This function returns the position of the end of the region (as an integer). This is the position of either point or the mark, whichever is larger.

If the mark does not point anywhere, an error is signaled.

Few programs need to use the region-beginning and region-end functions. A command designed to operate on a region should normally use interactive with the `r' specification to find the beginning and end of the region. This lets other Lisp programs specify the bounds explicitly as arguments. (See section Code Characters for interactive.)