class  Show a  where
    showsPrec        :: Int -> a -> ShowS
    show       :: a -> String 
    showList         :: [a] -> ShowS

-- Mimimal complete definition:
-- show or showsPrec
    showsPrec _ x s   = show x ++ s

    show x        = showsPrec 0 x ""

    showList []       = showString "[]"
    showList (x:xs)   = showChar '[' . shows x . showl xs
                        where showl []     = showChar ']'
                              showl (x:xs) = showChar ',' . shows x .
                                             showl xs

instance Show Int where

    showsPrec           = showSigned showInt

instance Show Integer where

    showsPrec           = showSigned showInt

instance Show Float where
 
    showsPrec p         = showFloat

instance Show Double where

    showsPrec p         = showFloat

instance Show () where

    showsPrec p () = showString "()"

instance Show Char where

    showsPrec p '\'' = showString "'\\''"
    showsPrec p c    = showChar '\'' . showLitChar c . showChar '\''

    showList cs = showChar '"' . showl cs
                 where showl ""       = showChar '"'
                       showl ('"':cs) = showString "\\\"" . showl cs
                       showl (c:cs)   = showLitChar c . showl cs

instance (Show a) => Show [a] where

    showsPrec p      = showList